#COMMENT

B R A I N S C A P E

An Adventure in Neuroanatomy

by W. Jeffrey Wilson & Lynne Ostergren

   Department of Psychological Sciences,
   Indiana University - Purdue University at Fort Wayne,
   2101 Coliseum Boulevard East,
   Fort Wayne, IN  46805.

Copyright, 1985 by Purdue Research Foundation, West Lafayette, Indiana 47907.

All Rights Reserved.  Unmodified copies of this program may be freely
distributed.  Each copy must contain this notice.

Adapted to AGT by David Malmberg in 1992


SCORING:
Visiting all 50 locations at 10 points each = 500 points

Getting treasure of "acetylcholine"         =  50 points
Getting treasure of "GABA"                  =  50 points
Getting treasure of "dopamine"              =  50 points
Getting treasure of "oligodendrocyte"       =  50 points
Getting treasure of "norepinephrine"        =  50 points
Getting treasure of "serotonin"             =  50 points
Getting treasure of "pyramidal cell"        =  50 points
Getting treasure of "Purkinje cell"         =  50 points
Getting treasure of "growth hormone"        =  50 points
Getting treasure of "Golgi Stain"           =  50 points

Pill Working when returning to heart        =  50 points
Having eaten "growth hormone"               =  50 points
Throwing "Golgi Stain" at ghost             =  50 points

TOTAL POINTS POSSIBLE                      = 1150 points

#END_COMMENT

MAXIMUM_SCORE 1150

REM -- STANDARD DEFAULT DEFINITIONS

#COMMENT Macros for special "rooms"
#DEFINE [Nowhere]        0
#DEFINE [Player]    1
#DEFINE [Wearing it]  1000

#COMMENT Macros for the directions used with ChangePassageway
#DEFINE [North]      1
#DEFINE [South]      2
#DEFINE [East]       3
#DEFINE [West]       4
#DEFINE [NorthEast]  5
#DEFINE [NorthWest]  6
#DEFINE [SouthEast]  7
#DEFINE [SouthWest]  8
#DEFINE [Up]         9
#DEFINE [Down]      10
#DEFINE [Enter]     11
#DEFINE [Exit]      12

#DEFINE [Can not exit #1] 1001
#DEFINE [Can not exit #2] 1002
#DEFINE [Not Yet] 1003

#DEFINE [Question] 0

MESSAGE [First Message -- Can not exit message #1]
Should I make my own door?  Moving $VERB$ from here is impossible.
END_MESSAGE

MESSAGE [Second Message -- Can not exit message #2]
You try to move $VERB$, but you bruise your nose.  You cannot move through
solid matter.
END_MESSAGE

MESSAGE [Third Message -- Sorry, not yet]
Sorry, but you can't pass that way ... yet!
END_MESSAGE


VARIABLE [Pill Working]
VARIABLE [Growing]

COMMAND ANY
NewLife -- First turn of game/life
SetVariableTo [Number of Wrong Answers] 0
SetVariableTo [Growing] 0
SetVariableTo [Pill Working] 11 ; You have just taken a pill
END_COMMAND

VERB
THROW STAIN
EAT SWALLOW
DOWN DO DORSAL
UP VE VENTRAL
WEST LA LATERAL
EAST ME MEDIAL
NORTH RO ROSTRAL
SOUTH CA CAUDAL
Dummy_Verb1 WRONGANSWER
Dummy_Verb2 MOVERANDOMLY
Dummy_Verb3 INFO
END_VERB

VOCABULARY
! This is the default AGT verb list for the "menu-driven" parser for BRAIN

! AGAIN should be the first A-verb
2 Attack
1 caudal
2 Close
1 DORSAL
2 Drop
2 Examine
2 Eat
! GET should be the first G-verb
2 Get
! HELP should be the first H-verb
1 Help
! INVENTORY should be the first I-verb
1 Inventory
1 info
1 LATERAL
1 Look around
3 Lock with
1 medial
! OPEN should be the first O-verb
2 Open
! QUIT should be the first Q-verb
1 Quit
1 rostral
! READ should be the first R-verb
2 Read
1 Restore
1 Score
1 Save
1 Scream
1 Script
2 swallow
! TAKE should be the first T-verb
2 Take
2 Throw
3 Unlock with
1 Unscript
1 VENTRAL
END_VOCABULARY

TITLE
B R A I N S C A P E

An Adventure in Neuroanatomy

by W. Jeffrey Wilson & Lynne Ostergren
Copyrighted 1985 by Purdue Research Foundation
Adapted to AGT by David Malmberg in 1992

END_TITLE


INSTRUCTIONS
Having stayed up late last night studying for your upcoming Neuroanatomy exam,
you slept fitfully, and awake none too refreshed.  At the foot of your bed you
find a shrouded figure, wizened and gray, speaking to you with a distinct Old
French accent.  "Bonjour.  Je m' appelle Rene Descartes.  O! Pardonez-moi!
Hello, Forgive me.  I am Rene Descartes," the figure says. "For years I have
pondered the mysteries of the Mind-Brain problem, and I am now convinced that
the only way to solve this philosophical impasse is to enter the brain itself
and have a look around.  A mechanism by which this is possible has occurred to
me, but I myself am too old and frail for such a trying journey.  You,
however, a promising student of Neuroanatomy, and far younger than I, are
ideal for the adventure."

Convinced that Descartes is nothing more than an after effect of the pepperoni
pizza that saw you through your long hours of study last night, you head for
the shower.  Descartes awaits you there, beckoning from the steamy stall, and
you join him.

"LISTEN CLOSELY AND REMEMBER MY WORDS!" he booms through the hot spray of
water.  "I am giving you two pills.  Take one now, and you will be safe from
the phagocytes and white blood cells of the immune system during your journey
through the blood supply to the brain.  Be sure to swallow the other one
before leaving the brain to journey back to the heart, where I can rescue you.
REMEMBER... If you enter your bloodstream without having first taken the pill,
you will surely not survive!"

Concerned now that a figment of your imagination is soaping your back, you
turn to confront Descartes.  His gaze pierces you, and he continues. "Once you
reach the brain you will be safe from most physical harm, as long as you
remain there.  You will undoubtedly be confronted with problems of many kinds.
In every case, your knowledge of Neuroanatomy and your uncommon good sense
will provide a solution.  Persevere!  No problem is insurmountable."

You realize now that he is serious, and figment or not, you may well soon find
yourself on your way to your own brain!  You begin to pay closer attention to
what Descartes has to say.

"You can move in any of the six anatomical directions:

        ROSTRAL: toward the head
         CAUDAL: toward the tail
         MEDIAL: toward the midline
        LATERAL: toward the side
         DORSAL: toward the top, or back
    and VENTRAL: toward the bottom, or stomach

"Indicate your intentions with phrases, such as ROSTRAL, GET DENDRITE, or DROP
MYELIN.  (Movement commands can be abbreviated by typing only the first two
letters of the direction in which you wish to move, i.e., RO for ROSTRAL,
etc.)

If you need to be reminded, just ask for INFO.

Several other commands might prove useful:

      INVENTORY:  Show what you are carrying
           LOOK:  Shows a description of current location
          SCORE:  Indicate your current score
           SAVE:  Save the current game on disk
        RESTORE:  Restore the last saved game from disk
       and QUIT:  Leave the current game

Through a process that you could never hope to understand, Descartes has
reduced you to a very small size, and is about to place you in your own
carotid artery for the journey to the brain.  "To gain the most knowledge from
this adventure, enter every area of the brain that you can.  Find the
treasures of the brain, and bring them back to me.  Solve the problems that
confront you.  And be absolutely certain that you bring back some growth
hormone, for without it I am powerless to return you to your normal size, and
you will remain miniscule forever."

"The anti-immune system pill has taken effect," Descartes assures you, as he
injects you into your carotid artery, "so you wll be safe from the phagocytes.
Enjoy this journey, and learn much from it!"

Still reeling with excitement, you ponder your situation.  You are now in your
own carotid artery, coursing toward your brain!  You feel the surge of each
heart beat as you are driven closer to your encounter with the very essence of
yourself.

Neuroanatomical terms occupy your thoughts during this, the most exciting
journey of your life....

       Rostral, Caudal, Ventral, Dorsal, Lateral, Medial!

If only you had paid more attention during that Neuro lecture!

The blood flows rapidly.  You pass through the circle of Willis and find
yourself... Yes! in the choroid plexus of the lateral ventricle!

With some of the blood plasma, you leave the choroid plexus and enter the
lateral ventricle itself.
END_INSTRUCTIONS


INTRODUCTION
Having wolfed down a pepperoni pizza and a pitcher of beer earlier in the
evening, you are sleeping very fitfully.  You thrash the pillow and turn over
and turn over again in the bed.  The sheets are wadded around you like ropes.
Your mind is filled with strange dreams....

END_INTRODUCTION


STARTING_ROOM [Lateral Ventricle]


NOUN [Pill]
pill
anti-immune
There is an anti-immune system pill here.
LOCATION [Player] ; carrying at start of game
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [Pill]
The anti-immune system pill is small and red in color.
END_NOUN_DESCR


ROOM [Lateral Ventricle]
Lateral Ventricle
DOWN  [Cingulate Gyrus] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Third Ventricle] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Lateral Ventricle]
This cavernous space is filled with cerebrospinal fluid, flowing medially
toward a small opening.  As you are carried by this flow, you notice a dorsal
passage that looks promising.
END_ROOM_DESCR


ROOM [Third Ventricle]
Third Ventricle
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Mammillary Body] ; VE or VENTRAL
WEST  [Thalamus]        ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Cerebral Aqueduct] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Third Ventricle]
In this narrow fluid-filled chamber you are being carried rapidly in a caudal
direction.  The thalamus looms large on either side of you, while ventrally
you can make out nuclei of the hypothalamus.
END_ROOM_DESCR


ROOM [Cerebral Aqueduct]
Cerebral Aqueduct
DOWN  [Peri Aqueductal Gray] ; DO or DORSAL
UP    [Peri Aqueductal Gray] ; VE or VENTRAL
WEST  [Peri Aqueductal Gray] ; LA or LATERAL
EAST  [Peri Aqueductal Gray] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Fourth Ventricle] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Cerebral Aqueduct]
This is a narrow passageway connecting the third and fourth ventricles. The
flow of cerebrospinal fluid is carrying you caudally quite rapidly! You are
surrounded by a gray region.
END_ROOM_DESCR


ROOM [Fourth Ventricle]
Fourth Ventricle
DOWN  [Cerebellum] ; DO or DORSAL
UP    [Medulla] ; VE or VENTRAL
WEST  [Lateral Lemniscus] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Foramen] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Fourth Ventricle]
This is a large space filled with cerebrospinal fluid.  The cerebellum towers
above you, and several structures are apparent ventrally.
END_ROOM_DESCR

COMMAND ANY
AtLocation [Fourth Ventricle]
VariableEquals [Pill Working] 0 ; Pill is not currently in effect
PrintMessage
WARNING!  WARNING!  You are in the fourth ventricle!  Do not proceed caudally
without your anti-immune system pill.  Without it, you will be devoured by the
phagocytes and white blood cells of the immune system!

END_MESSAGE
END_COMMAND


ROOM [Foramen]
Foramen of Magendie
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [SubArachnoid] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Foramen]
The cerebrospinal fluid is surging through this small opening into the
subarachnoid space.  You will soon begin your journey back to the heart.
END_ROOM_DESCR

COMMAND ANY
AtLocation [Foramen]
VariableEquals [Pill Working] 0 ; Pill is not currently in effect
PrintMessage
DANGER!  DANGER!  You must take an anti-immune system pill NOW!

END_MESSAGE
END_COMMAND



ROOM [SubArachnoid]
Subarachnoid Space
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [SubArachnoid]
You are being swept forcefully toward an arachnoid villus, and a reunion with
the blood supply.
END_ROOM_DESCR


ROOM [Caudate Head]
Head of the Caudate Nucleus
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Caudate Tail] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Caudate Head]
This large forebrain structure is a major component of the extrapyramidal
motor system and, with the putamen, makes up the corpus striatum.  You were
able to enter the caudate by way of the nigrostriatal bundle because you were
carrying dopamine.  The structure narrows considerably in the caudal
direction, but there appears to be an opening there.
END_ROOM_DESCR

NOUN [ACh]
acetylcholine
none
There is some acetylcholine here.
LOCATION [Caudate Head]
POINTS 50 ; This is a 50 point "treasure"
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [ACh]
Acetylcholine is a neurotransmitter of sympathetic preganglionic fibers.
END_NOUN_DESCR


ROOM [Caudate Tail]
Tail of the Caudate Nucleus
DOWN  [Amygdala] ; DO or DORSAL
UP    [Amygdala] ; VE or VENTRAL
WEST  [Amygdala] ; LA or LATERAL
EAST  [Amygdala] ; ME or MEDIAL
NORTH [Amygdala] ; RO or ROSTRAL
SOUTH [Amygdala] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Caudate Tail]
This narrow tail of the caudate is quite slippery, and the footing is very
treacherous.  The tail curves laterally and ventrally out of view in a caudal
direction.
END_ROOM_DESCR

COMMAND ANY
VerbIsDirection
AtLocation [Caudate Tail]
PrintMessage 
You have lost your footing, and are slipping down the long, twisting tail of
the caudate nucleus....
END_Message
GoToRoom [Amygdala]
DoneWithTurn
END_COMMAND

ROOM [Putamen]
Putamen
DOWN  [Internal Capsule] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Pallidum] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Putamen]
The putamen is a component of the corpus striatum and the lentiform nucleus. A
large number of myelinated fibers make up the roof, and provide easy handholds
for an exit in that direction.  A soft white glow enters the room from the
medial direction.
END_ROOM_DESCR


ROOM [Pallidum]
Globus Pallidus
DOWN  [Internal Capsule] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Putamen] ; LA or LATERAL
EAST  [Accumbens -- Thief's Lair] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM


ROOM_DESCR [Pallidum]
This extrapyramidal structure, together with the more lateral putamen, makes
up the lentiform nucleus.  The lentiform nucleus and corpus striatum together
make up the major telencephalic component of the basal ganglia.  The ceiling
here is composed of large myelinated fibers, perfect for climbing.  A small,
almost invisible passage leads in a medial direction.
END_ROOM_DESCR

NOUN [GABA]
GABA
none
There is some GABA here.
LOCATION [Pallidum]
POINTS 50 ; This is a 50 point "treasure"
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [GABA]
GABA is a neurotransmitter.
END_NOUN_DESCR


ROOM [Nigra]
Substantia Nigra
DOWN  [Peri Aqueductal Gray] ; DO or DORSAL
UP    [Cerebral Peduncle] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Nigro Striatal Bundle] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Nigra]
This darkly pigmented area produces much of the dopamine found in the brain. A
long, twisting passageway leads in a rostral direction, and you can see a
myelinated highway ventral to your current location.  A wet, gray region lies
dorsal to you.
END_ROOM_DESCR

NOUN [DA]
dopamine
none
There is some dopamine here.
LOCATION [Nigra]
weight 9 ; can carry only ten items
size 9
POINTS 50 ; This is a 50 point "treasure"
END_NOUN

NOUN_DESCR [DA]
The striatum has remarkably high concentration of a number of
neurotransmitters, including dopamine.  Tracts carrying impulses from the
substantia nigra to the caudate and putamen store dopamine in their terminals.
This represents the most important source of dopamine in the striatum.
Failure of dopamine synthesis in the substantia nigra results in progressive
depletion of this critical neurotransmitter in the caudate and putamen, with a
consequent develoment of Parkinson's disease.  The characteristic signs of
this crippling illness (tremor at rest, muscle rigidity, and abnormal gait)
are to some extent reversible upon adminstration of the dopamine precursor,
L-dopa.
END_NOUN_DESCR


ROOM [Internal Capsule]
Internal Capsule
DOWN  [Motor Strip] ; DO or DORSAL
UP    [Pallidum] ; VE or VENTRAL
WEST  [Putamen] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Cerebral Peduncle] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Internal Capsule]
You are on a heavily myelinated highway that originates somewhere dorsal to
your present position, and extends caudally as far as you can see.  Passages
extend laterally and ventrally.
END_ROOM_DESCR


ROOM [Cerebral Peduncle]
Cerebral Peduncle
DOWN  [Nigra] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Internal Capsule] ; RO or ROSTRAL
SOUTH [Pons] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Cerebral Peduncle]
The heavily myelinated highway that you find yourself on extends both
rostrally and caudally.  A dark cluster of cell bodies is apparent dorsally.
END_ROOM_DESCR

NOUN [Oligodendrocyte]
oligodendrocyte
large
There is a large oligodendrocyte here.
LOCATION [Cerebral Peduncle]
POINTS 50 ; This is a 50 point "treasure"
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [Oligodendrocyte]
Oligodendrocytes ("oligo" means "few" in Latin, "dendro" means "tree" -- so,
"oligodendrocytes" means "few treelike processes") are smaller than astrocytes
and have fewer processes.
END_NOUN_DESCR


ROOM [Nigro Striatal Bundle]
Nigrostriatal Bundle
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Caudate Head] ; RO or ROSTRAL -- if player has NOUN [DA]
SOUTH [Nigra] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Nigro Striatal Bundle]
This caudal-rostral pathway runs from the substantia nigra to the caudate
nucleus, bringing dopaminergic fibers from the midbrain to the forebrain.
END_ROOM_DESCR

COMMAND ROSTRAL
AtLocation [Nigro Striatal Bundle]
NOT Present [DA]
PrintMessage "Sorry, but you need dopamine to go that way!"
DoneWithTurn
END_COMMAND


ROOM [Thalamus]
Thalamus
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [LHA] ; VE or VENTRAL
WEST  [Lateral Geniculate] ; LA or LATERAL
EAST  [Third Ventricle] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Medial Geniculate] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Thalamus]
Welcome to a major relay station of your brain, the Thalamus, which takes
sensory information and relays it to the cortex.  Afferent pathways on their
way to the cortex synapse here, as do efferent fibers leaving the cortex.
Passages extend away from you in all directions except dorsally and rostrally.
END_ROOM_DESCR

NOUN [Ves5HT]
vesicle
serotonergic
There is a serotonergic vesicle here.
LOCATION [Thalamus]
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [Ves5HT]
The serotonergic vesicle looks fairly normal.
END_NOUN_DESCR


ROOM [Pons]
Pons
DOWN  [Ventral Norad Bundle] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Raphe] ; ME or MEDIAL
NORTH [Cerebral Peduncle] ; RO or ROSTRAL
SOUTH [Medulla] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Pons]
This mesencephalic landmark contains many groups of cell bodies, as well as
fibers that extend to the cerebellum.  The corticospinal fibers that make up
the cerebral peduncles rostrally continue through the pons and extend
caudally.  A narrow bundle of fibers extends dorsally, and you can see a group
of cells in the medial direction.
END_ROOM_DESCR

NOUN [NE]
norepinephrine
none
There is some norepinephrine here.
LOCATION [Pons]
POINTS 50 ; This is a 50 point "treasure"
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [NE]
It looks fairly normal.
END_NOUN_DESCR


ROOM [Medulla]
Medulla
DOWN  [Fourth Ventricle] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Raphe] ; ME or MEDIAL
NORTH [Pons] ; RO or ROSTRAL
SOUTH [Pyramids] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Medulla]
This primitive part of the brain, in the myelencephalon, controls vegetative
processes essential to life.  The sound of running water is quite strong
dorsally.  This region nears the end of a long rostral-caudal highway, and you
can see some fibers decussating caudally.  A passage leads medially.
END_ROOM_DESCR


ROOM [Raphe]
Raphe Nuclei
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Medulla] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Peri Aqueductal Gray] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Raphe]
This midline group of cell bodies forms the core of both the pons and the
medulla.  For some reason, you feel quite drowsy.
END_ROOM_DESCR

NOUN [SER]
serotonin
none
There is some serotonin here.
LOCATION [Raphe]
POINTS 50 ; This is a 50 point "treasure"
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [SER]
It looks fairly normal.
END_NOUN_DESCR

ROOM [Lateral Lemniscus]
Lateral Lemniscus
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Fourth Ventricle] ; ME or MEDIAL
NORTH [Inferior Colliculus] ; RO or ROSTRAL
SOUTH [Trapezoid Body] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Lateral Lemniscus]
These myelinated fibers form part of the auditory pathway.  You hear sounds
that seem to originate in a medial direction.  A small hill rises on the
rostral horizon.  A narrow pathway leads caudally.
END_ROOM_DESCR


ROOM [Ventral Norad Bundle]
Ventral Noradrenergic Bundle
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Thalamus] ; RO or ROSTRAL
SOUTH [Pons] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Ventral Norad Bundle]
This caudal-rostral pathway consists of noradrenergic fibers that lead from
the locus coeruleus in the pons to the forebrain.
END_ROOM_DESCR

COMMAND ROSTRAL
AtLocation [Ventral Norad Bundle]
NOT Present [NE]
PrintMessage "Sorry, but you need noreprinephrine to go that way!"
DoneWithTurn
END_COMMAND


ROOM [Inferior Colliculus]
Inferior Colliculus
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Peri Aqueductal Gray] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Medial Geniculate] ; RO or ROSTRAL
SOUTH [Lateral Lemniscus] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Inferior Colliculus]
You are on a small hill in the auditory system.  This structure forms part of
the tectum, the roof of the mesencephalon.  You can move rostrally, caudally,
or ventrally.
END_ROOM_DESCR


ROOM [Medial Geniculate]
Medial Geniculate Nucleus
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Auditory Cx] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Thalamus] ; RO or ROSTRAL
SOUTH [Inferior Colliculus] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Medial Geniculate]
This auditory relay nucleus is located at the caudal end of the thalamus.  A
path radiates laterally from this point, and a small hill can be seen caudally
in the distance.
END_ROOM_DESCR


ROOM [Trapezoid Body]
Trapezoid Body
DOWN  [Question] ; DO or DORSAL
UP    [Question] ; VE or VENTRAL
WEST  [Question] ; LA or LATERAL
EAST  [Question] ; ME or MEDIAL
NORTH [Question] ; RO or ROSTRAL
SOUTH [Question] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Trapezoid Body]
This brainstem nucleus is the most peripheral part of the auditory system that
you can enter.  There is no obvious exit.
END_ROOM_DESCR


ROOM [Peri Aqueductal Gray]
PeriAqueductal Grey Matter
DOWN  [Inferior Colliculus] ; DO or DORSAL
UP    [Nigra] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Cerebral Aqueduct] ; ME or MEDIAL
NORTH [Superior Colliculus] ; RO or ROSTRAL
SOUTH [Raphe] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Peri Aqueductal Gray]
This region surrounding the cerebral aqueduct plays a role in the modulation
of pain.  Electrical stimulation of this area produces profound analgesia. A
large hill rises rostrally, a small hill dorsally, a dark group of cells lies
ventrally, and a path leads caudally.  You hear rapidly flowing fluid in the
medial direction.
END_ROOM_DESCR


ROOM [Auditory Cx]
Auditory Cortex
DOWN  [Brocas] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Medial Geniculate] ; ME or MEDIAL
NORTH [Assoc Cx] ; RO or ROSTRAL
SOUTH [Wernickes] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Auditory Cx]
Whirr - TICKTOCK - Meeoowwww - TraLaLaLa - CRASH - "Fourscore and seven years"
Voices, music, and every imaginable sound envelope you.  Words seem quite loud
in both the dorsal and caudal direction, and a bundle of fibers extends
medially.  The landscape is hazy in the rostral direction.
END_ROOM_DESCR


ROOM [Suprachias Nuc]
Suprachiasmatic Nucleus
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Optic Chiasm] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Suprachias Nuc]
This small structure is thought to be involved in the regulation of circadian
rhythms.  You can see the optic chiasm ventrally.
END_ROOM_DESCR

NOUN [VesDA]
vesicle
dopamine
There is a vesicle that once contained dopamine here.
LOCATION [Suprachias Nuc]
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [VesDA]
It looks fairly normal.
END_NOUN_DESCR

ROOM [Pituitary]
Pituitary Gland
DOWN  [Question] ; DO or DORSAL
UP    [Question] ; VE or VENTRAL
WEST  [Question] ; LA or LATERAL
EAST  [Question] ; ME or MEDIAL
NORTH [Question] ; RO or ROSTRAL
SOUTH [Question] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Pituitary]
Also known as the hypophysis, this endocrine organ is often called the "master
gland" of the body.  Under the control of the hypothalamus, it secretes a
variety of hormones.  There is no obvious way out.
END_ROOM_DESCR

NOUN [GrowthHormone]
Hormone
Growth
There is a bottle labeled "Growth Hormone: Promotes growth and strength."
LOCATION [Pituitary]
POINTS 50 ; This is a 50 point "treasure"
NOUN_SYNONYMS Bottle
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [GrowthHormone]
It looks fairly normal.
END_NOUN_DESCR

ROOM [Pyramids]
Pyramids
DOWN  [Question] ; DO or DORSAL
UP    [Question] ; VE or VENTRAL
WEST  [Question] ; LA or LATERAL
EAST  [Question] ; ME or MEDIAL
NORTH [Question] ; RO or ROSTRAL
SOUTH [Question] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Pyramids]
Here fibers of the corticospinal tract cross to opposite sides of the
brainstem before descending to terminate in the spinal cord.  There is no
obvious way out.
END_ROOM_DESCR

NOUN [Key]
key
rusty
There is a rusty key here.
LOCATION [Pyramids]
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [Key]
It looks fairly normal.
END_NOUN_DESCR

ROOM [Cingulate Gyrus]
Cingulate Gyrus
DOWN  [Motor Strip] ; DO or DORSAL
UP    [Lateral Ventricle] ; VE or VENTRAL
WEST  [Sensory Strip] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Frontal Lobe] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Cingulate Gyrus]
This band of limbic cortex allows passage in all directions except medially
and caudally.
END_ROOM_DESCR


ROOM [Optic Tract]
Optic Tract
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Superior Colliculus] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Optic Chiasm] ; RO or ROSTRAL
SOUTH [Lateral Geniculate] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Optic Tract]
This bundle of fibers carries visual infomation caudally to the lateral
geniculate nucleus in the thalamus.  The fibers appear to decussate somewhat
rostrally to here.  A large hill is barely visible in the ventral distance.
END_ROOM_DESCR


ROOM [Optic Chiasm]
Optic Chiasm
DOWN  [Suprachias Nuc] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Optic Tract] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Optic Chiasm]
Optic nerve fibers from the nasal half of each retina cross here on their way
to the lateral geniculate nucleus via the optic tracts.  A large bundle of
fibers extends caudally, and a small path leads dorsally.
END_ROOM_DESCR


ROOM [Lateral Geniculate]
Lateral Geniculate Nucleus
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Superior Colliculus] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Thalamus] ; ME or MEDIAL
NORTH [Optic Tract] ; RO or ROSTRAL
SOUTH [Optic Radiation] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Lateral Geniculate]
Visual information is relayed caudally from this point to the occipital lobe
of the cortex.  The optic tract enters from a rostral direction, and the rest
of the thalamus lies medial to your current position.  A large hill is just
apparent in a ventral direction.
END_ROOM_DESCR


ROOM [Superior Colliculus]
Superior Colliculus
DOWN  [Lateral Geniculate] ; DO or DORSAL
UP    [Peri Aqueductal Gray] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Optic Tract] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Superior Colliculus]
This large hill, together with the inferior colliculus, forms the tectum, the
roof of the mesencephalon.  The superior colliculus is involved in visual
tracking and reflexive eye movements.  A steep path descends ventrally into a
nondescript, gray region.  Other passages lead both dorsally and rostrally.
END_ROOM_DESCR


ROOM [Optic Radiation]
Optic Radiation
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Visual Cx] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Optic Radiation]
This pathway conveys visual information from the lateral geniculate nucleus to
the visual cortex in the occipital lobe.
END_ROOM_DESCR


ROOM [Visual Cx]
Visual Cortex
DOWN  [Question] ; DO or DORSAL
UP    [Question] ; VE or VENTRAL
WEST  [Question] ; LA or LATERAL
EAST  [Question] ; ME or MEDIAL
NORTH [Question] ; RO or ROSTRAL
SOUTH [Question] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Visual Cx]
Lights, colors, forms, shapes and patterns of every conceivable shade, hue and
brightness dance around you.  This is the cortical area concerned with visual
information processing.  There is no obvious way out.
END_ROOM_DESCR


ROOM [Amygdala]
Amygdala
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Question] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Question] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Amygdala]
The Amygdala generates emotiuons from perceptions and thoughts.  This
structure is often grouped with both the basal ganglia and the limbic system.
It probably subserves aggression or rage.  Passages lead caudally and
medially.
END_ROOM_DESCR

ROOM [Septum]
Septum
DOWN  [Fornix] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Not Yet] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Mammillary Body] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Septum]
This limbic system structure seems to inhibit rage or emotionality, for
lesioning it produces the "septal rage" phenomenon in rats.  A tunnel leads
laterally, and other paths lead dorsally and caudally.
END_ROOM_DESCR


NOUN [Scrap]
scrap
paper
There is a scrap of paper here.
LOCATION [Septum]
NOUN_SYNONYMS paper
weight 9 ; can carry only ten items
size 9
READABLE
END_NOUN

NOUN_DESCR [Scrap]
It looks fairly normal.
END_NOUN_DESCR

TEXT [Scrap]
"We hope you are enjoying BRAINSCAPE!

Please send comments, suggestions, or pleas for help to:

   W. Jeffrey Wilson, Ph.D.
   Dept. of Psychological Sciences
   Indiana University-Purdue University
   Fort Wayne, IN  46805"
END_TEXT


ROOM [Mammillary Body]
Mammillary Body
DOWN  [Fornix] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [LHA] ; ME or MEDIAL
NORTH [Septum] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Mammillary Body]
This hypothalamic region is implicated in both emotionality and sexual
behavior.  An intriguing road lies dorsally, and a narrow path rostrally.
Moving medially causes intense hunger pangs.
END_ROOM_DESCR


ROOM [Hippocampus]
Hippocampus
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Fornix] ; ME or MEDIAL
NORTH [Not Yet] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Hippocampus]
The Hippocampus consolidates recently acquired information, somehow turning
short-term memory into long term.  Memories well up within you in this
structure that is thought to play a role in memory consolidation.  A
myelinated pathway leads medially, and a small passageway leaves in a rostral
direction.
END_ROOM_DESCR

NOUN [VesACh]
vesicle
acetylcholine
There is a vesicle with traces of acetylcholine on it here.
LOCATION [Hippocampus]
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [VesACh]
It looks fairly normal.
END_NOUN_DESCR

ROOM [Fornix]
Fornix
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Mammillary Body] ; VE or VENTRAL
WEST  [Hippocampus] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Septum] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Fornix]
This band of fibers interconnects the hippocampus, septal area, and
mammillary bodies of the hypothalamus.  The fibers extend ventrally,
rostrally, and laterally.
END_ROOM_DESCR


ROOM [VMN]
Ventromedial Nucleus of the Hypothalamus
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Pituitary] ; VE or VENTRAL
WEST  [LHA] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [VMN]
You feel quite satiated within this hypothalamic nucleus, felt to play a role
in the inhibition of food intake.  Moving laterally gives rise to feelings of
hunger, while ventral movement gets your hormones flowing.
END_ROOM_DESCR

NOUN [VesNE]
vesicle
noradrenergic
There is a noradrenergic vesicle here.
LOCATION [VMN]
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [VesNE]
It looks fairly normal.
END_NOUN_DESCR

ROOM [LHA]
Lateral Hypothalamic Area
DOWN  [Thalamus] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [VMN] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Mammillary Body] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [LHA]
Severe hunger grips you here, but it seems to subside as you approach a medial
passage.  A large structure looms above you, and a passageway leads caudally.
END_ROOM_DESCR


ROOM [Sensory Strip]
Sensory Strip
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Cingulate Gyrus] ; ME or MEDIAL
NORTH [Motor Strip] ; RO or ROSTRAL
SOUTH [Assoc Cx] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Sensory Strip]
Shocks race through you, fingers caress you, pins prick at you, and feathers
brush your skin here in the cortical area that mediates somatosensation. There
is some movement rostrally, and the terrain slopes downward medially. In the
caudal direction, things are somewhat hazy.
END_ROOM_DESCR


ROOM [Motor Strip]
Motor Strip
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Internal Capsule] ; VE or VENTRAL
WEST  [Brocas] ; LA or LATERAL
EAST  [Cingulate Gyrus] ; ME or MEDIAL
NORTH [Frontal Lobe] ; RO or ROSTRAL
SOUTH [Sensory Strip] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Motor Strip]
Voluntary motor control resides here, exerting its influence via the bundle of
fibers descending ventrally below you.  You can move in all directions except
dorsally.
END_ROOM_DESCR

NOUN [PyramidalCell]
cell
pyramidal
There is a pyramidal cell here.
LOCATION [Motor Strip]
POINTS 50 ; This is a 50 point "treasure"
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [PyramidalCell]
It looks fairly normal.
END_NOUN_DESCR

ROOM [Frontal Lobe]
Frontal Lobe
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Cingulate Gyrus] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Motor Strip] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Frontal Lobe]
This region of the cortex is concerned primarily with motor control, speech
and planning, but is also implicated in various aspects of that nebulous
feature of us all, our personality.  You can move both caudally and medially.
END_ROOM_DESCR


ROOM [Brocas]
Broca's Area
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Auditory Cx] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Motor Strip] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Wernickes] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Brocas]
This area of the frontal lobe plays an important role in speech production.
Faint sounds originate ventrally, and you sense movement medially.  An
important area seems to lie caudal to this, but its name escapes you.
END_ROOM_DESCR


ROOM [Wernickes]
Wernicke's Area
DOWN  [Brocas] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Auditory Cx] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Wernickes]
You know what this place is, but you cannot find the words to name it.  It is
involved in speech, you think.  Several passageways lead out of this area, but
you cannot think of the names of the directions in which they lead.
END_ROOM_DESCR

NOUN [VesGABA]
vesicle
GABA
There is a vesicle for GABA here.
LOCATION [Wernickes]
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [VesGABA]
It looks fairly normal.
END_NOUN_DESCR


ROOM [Assoc Cx]
Association Cortex
DOWN  [Assoc1] ; DO or DORSAL
UP    [Assoc2] ; VE or VENTRAL
WEST  [Assoc3] ; LA or LATERAL
EAST  [Assoc5] ; ME or MEDIAL
NORTH [Assoc1] ; RO or ROSTRAL
SOUTH [Assoc2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Assoc Cx]
Recollections dance around you here.  You hear music that reminds you of a
place that you once visited.  You met someone there, and can see her face.
The way out is none too clear, and your memories haunt you.
END_ROOM_DESCR


ROOM [Accumbens -- Thief's Lair]
Nucleus Accumbens
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Can not exit #2] ; VE or VENTRAL
WEST  [Pallidum] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Accumbens -- Thief's Lair]
This region, poised between the limbic system and the basal ganglia, is
thought to allow emotions to gain access to the motor system.  The only way
out is laterally, the way you came in.
END_ROOM_DESCR

NOUN [Locked Chest]
chest
wooden
There is an old wooden chest attached to the wall here.  It is closed.
LOCATION [Accumbens -- Thief's Lair]
SIZE 95
WEIGHT 95
UNMOVABLE
CLOSABLE
CLOSED
LOCKABLE
LOCKED
KEY [Key]
NOUN_SYNONYMS Padlock Lock Doors Door
END_NOUN

NOUN_DESCR [Locked Chest]
It has ornately carved wooden doors, and a big, rusty padlock.  It is closed
and locked.
END_NOUN_DESCR

NOUN [Unlocked Chest]
chest
wooden
There is an old wooden chest attached to the wall here.  It is open.
LOCATION [Nowhere]
SIZE 95
WEIGHT 95
UNMOVABLE
CLOSABLE
OPEN
LOCKABLE
UNLOCKED
KEY [Key]
NOUN_SYNONYMS Padlock Lock Doors Door
END_NOUN

NOUN_DESCR [Unlocked Chest]
It has ornately carved wooden doors, and a big, rusty padlock.  It is unlocked
and open.
END_NOUN_DESCR


NOUN [GolgiStainVial]
vial
crystal
There is a delicate crystal vial with a faded label here.
LOCATION [Unlocked Chest]
weight 9 ; can carry only ten items
size 9
READABLE
NOUN_SYNONYMS Label
END_NOUN

NOUN_DESCR [GolgiStainVial]
It looks fairly normal.
END_NOUN_DESCR

TEXT [GolgiStainVial]
You can barely make out the faded characters.
             "ACME Golgi Stain
      for silver impregnation of cells
         (and cantankerous ghosts!)"
END_TEXT

NOUN [GolgiStain]
stain
golgi
There is a vial of Golgi Stain here.
LOCATION [NoWhere]
POINTS 50 ; This is a 50 point "treasure"
weight 9 ; can carry only ten items
size 9
READABLE
NOUN_SYNONYMS Label Vial
END_NOUN

NOUN_DESCR [GolgiStain]
It looks fairly normal.
END_NOUN_DESCR

TEXT [GolgiStain]
You can barely make out the faded characters.
             "ACME Golgi Stain
      for silver impregnation of cells
         (and cantankerous ghosts!)"
END_TEXT


MESSAGE [GolgiStain Label]
You can barely make out the faded characters.
             "ACME Golgi Stain
      for silver impregnation of cells
         (and cantankerous ghosts!)"
END_MESSAGE

COMMAND READ LABEL
Present [GolgiStainVial]
PrintMessage  [GolgiStain Label]
SwapLocations [GolgiStainVial] [GolgiStain]
DoneWithTurn
END_COMMAND


MESSAGE [Unlock and open]
The padlock opens readily with your key!  You open the chest and find a vial,
with any old and yellowed label.
END_MESSAGE

COMMAND UNLOCK CHEST
Present [Locked Chest]
Present [Key]
SwapLocations [Locked Chest] [Unlocked Chest]
PrintMessage [Unlock and open]
DoneWithTurn
END_COMMAND

NOUN [Glass]
glass
broken
There is some broken glass here.
LOCATION [NoWhere]
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [Glass]
It looks fairly normal.
END_NOUN_DESCR

COMMAND DROP VIAL
Present [GolgiStainVial]
AtLocationGT [Foramen]
Destroy [GolgiStainVial]
DropIT [Glass]
PrintMessage "The crystal vial shatters as it hits the floor!"
DoneWithTurn
END_COMMAND

COMMAND DROP STAIN
Present [GolgiStain]
AtLocationGT [Foramen]
Destroy [GolgiStain]
DropIT [Glass]
PrintMessage "The crystal vial shatters as it hits the floor!"
DoneWithTurn
END_COMMAND


ROOM [Cerebellum]
Cerebellum
DOWN  [Can not exit #1] ; DO or DORSAL
UP    [Fourth Ventricle] ; VE or VENTRAL
WEST  [Can not exit #1] ; LA or LATERAL
EAST  [Can not exit #2] ; ME or MEDIAL
NORTH [Can not exit #1] ; RO or ROSTRAL
SOUTH [Can not exit #2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Cerebellum]
You are in the Cerebellum which governs muscle coordination and the learning
of rote movements.  This delicately structured "small brain" sits atop your
brainstem, and controls coordinated movements.  It may also play a role in
learning.  The sound of flowing liquid is quite loud ventrally.
END_ROOM_DESCR

NOUN [PurkinjeCell]
cell
Purkinje
There is a Purkinje cell here.
LOCATION [Cerebellum]
POINTS 50 ; This is a 50 point "treasure"
weight 9 ; can carry only ten items
size 9
END_NOUN

NOUN_DESCR [PurkinjeCell]
It looks fairly normal.
END_NOUN_DESCR


ROOM [Assoc1]
Association Cortex
DOWN  [Assoc2] ; DO or DORSAL
UP    [Assoc3] ; VE or VENTRAL
WEST  [Assoc4] ; LA or LATERAL
EAST  [Assoc5] ; ME or MEDIAL
NORTH [Assoc2] ; RO or ROSTRAL
SOUTH [Assoc3] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Assoc1]

This is a different region of the association cortex.
END_ROOM_DESCR


ROOM [Assoc2]
Association Cortex
DOWN  [Assoc3] ; DO or DORSAL
UP    [Assoc4] ; VE or VENTRAL
WEST  [Assoc5] ; LA or LATERAL
EAST  [Assoc1] ; ME or MEDIAL
NORTH [Assoc3] ; RO or ROSTRAL
SOUTH [Assoc4] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Assoc2]

This part of the association cortex is different from the one you just left.
END_ROOM_DESCR


ROOM [Assoc3]
Association Cortex
DOWN  [Assoc4] ; DO or DORSAL
UP    [Assoc5] ; VE or VENTRAL
WEST  [Assoc1] ; LA or LATERAL
EAST  [Assoc2] ; ME or MEDIAL
NORTH [Assoc4] ; RO or ROSTRAL
SOUTH [Assoc5] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Assoc3]

Association cortex all looks alike, yet this looks different somehow.
END_ROOM_DESCR


ROOM [Assoc4]
Association Cortex
DOWN  [Assoc5] ; DO or DORSAL
UP    [Assoc1] ; VE or VENTRAL
WEST  [Assoc2] ; LA or LATERAL
EAST  [Assoc3] ; ME or MEDIAL
NORTH [Assoc5] ; RO or ROSTRAL
SOUTH [Assoc1] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Assoc4]

You seem to be free associating.
END_ROOM_DESCR


ROOM [Assoc5]
Association Cortex
DOWN  [Assoc1] ; DO or DORSAL
UP    [Assoc2] ; VE or VENTRAL
WEST  [Assoc3] ; LA or LATERAL
EAST  [Assoc4] ; ME or MEDIAL
NORTH [Assoc1] ; RO or ROSTRAL
SOUTH [Assoc2] ; CA or CAUDAL
POINTS 10 ; each room visited is worth 10 points
END_ROOM

ROOM_DESCR [Assoc5]

You must like this part of your brain.
END_ROOM_DESCR


#COMMENT Player must move ROSTRAL then LATERAL (in sequence) to escape from
#COMMENT Association Cortex "maze"

FLAG [In Association Cortex] -- player in the Association Cortex "maze"
FLAG [Last Direction was ROSTRAL] -- means player went ROSTRAL last turn


COMMAND ANY
TurnFlagOFF [In Association Cortex]
AtLocationGT [Cerebellum]
AtLocationLT [WakeUp]
TurnFlagON [In Association Cortex]
END_COMMAND

COMMAND LATERAL
FlagON [In Association Cortex]
FlagON [Last Direction was ROSTRAL]
GoToRoom [Frontal Lobe] ; escape to ROOM [Frontal Lobe]
TurnFlagOFF [In Association Cortex]
TurnFlagOFF [Last Direction was ROSTRAL]
DoneWithTurn
END_COMMAND

COMMAND ROSTRAL
FlagON [In Association Cortex]
TurnFlagON [Last Direction was ROSTRAL]
END_COMMAND

COMMAND CAUDAL
FlagON [In Association Cortex]
TurnFlagOFF [Last Direction was ROSTRAL]
END_COMMAND

COMMAND MEDIAL
FlagON [In Association Cortex]
TurnFlagOFF [Last Direction was ROSTRAL]
END_COMMAND

COMMAND DORSAL
FlagON [In Association Cortex]
TurnFlagOFF [Last Direction was ROSTRAL]
END_COMMAND

COMMAND VENTRAL
FlagON [In Association Cortex]
TurnFlagOFF [Last Direction was ROSTRAL]
END_COMMAND


MESSAGE [INFO Message]
You can move in any of the six anatomical directions:

        ROSTRAL: toward the head
         CAUDAL: toward the tail
         MEDIAL: toward the midline
        LATERAL: toward the side
         DORSAL: toward the top, or back
    and VENTRAL: toward the bottom, or stomach

Indicate your intentions with phrases, such as ROSTRAL, GET DENDRITE, or DROP
MYELIN.  (Movement commands can be abbreviated by typing only the first two
letters of the direction in which you wish to move, i.e., RO for ROSTRAL,
etc.)

Several other commands might prove useful:

      INVENTORY:  Show what you are carrying
           LOOK:  Shows a description of current location
          SCORE:  Indicate your current score
           SAVE:  Save the current game on disk
        RESTORE:  Restore the last saved game from disk
       and QUIT:  Leave the current game

END_MESSAGE


COMMAND INFO
PrintMessage [INFO Message]
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation [SubArachnoid]
PrintMessage
From the Subarachnoid space you are swept through an arachnoid granulation and
into the venous system through which blood leaves the brain.

END_Message
VariableEquals [Pill Working] 0 ; Pill is currently not in effect
PrintMessage
Unprotected by the anti-immune system pill, you are quickly engulfed by white
blood cells.  Your final thought is of the knowledge you gained in this
adventure, and of how foolish you were not to use it.
END_Message
ReDirectTo QUIT
END_COMMAND

COMMAND ANY
AtLocation [SubArachnoid]
VariableGT [Pill Working] 0 ; Pill is currently in effect
PlusScore 50
PrintMessage
White blood cells gather hungrily around you, but you are protected from them
by the powerful medication provided by Descartes.

You find yourself in the jugular vein, leaving the head and coursing back
toward the heart.  Fear grips you as you wonder whether or not you will be
rescued by Descartes before the contractions of the heart crush you.

Descartes appears, just in time to save you.

END_Message
END_COMMAND

COMMAND ANY
AtLocation [SubArachnoid]
VariableEquals [Growing] 0 ; Has not taken Growth Hormone
NOT Present [GrowthHormone] ; You don't have it either
PrintMessage
"Without growth hormone, you will remain tiny for the rest of your life,"
Descartes moans.  "There is nothing I can do!"
END_Message
ReDirectTo QUIT
END_COMMAND

COMMAND ANY
AtLocation [SubArachnoid]
#COMMENT -- Has taken Growth Hormone or is carrying it
PrintMessage
"Marvelous!  You found the growth hormone! Now you can return to your normal
size!" Descartes cries with relief.
END_Message
ReDirectTo QUIT
END_COMMAND

ROOM [WakeUp]
You wake up in your own bed!
GAME_END ; this is the program "exit"
END_ROOM

ROOM_DESCR [WakeUp]
You awaken to the sound of the alarm clock, your head spinning with
neuroanatomical terminology.  Rather than feeling refreshed, you feel oddly as
if the night had been spent in deep concentration.  No time to dwell on that
now.  You've got to get ready for that neuroanatomy exam....

END_ROOM_DESCR


CREATURE [Homunculus]
Homunculus
Purkinje
The Homunculus is eyeing you with interest.
LOCATION [Sensory Strip]
MAN
FRIENDLY
GROUPMEMBER ; Homunculus follows player
END_CREATURE

CREATURE_DESCR [Homunculus]
There is a small, oddly shaped man here.  He has a huge mouth, gigantic hands,
and a tiny torso.  It is a Homunculus!
END_CREATURE_DESCR

FLAG [Has met Homunculus]

COMMAND ANY
NOT Present [Homunculus]
FlagON [Has met Homunculus]
Chance 10 ; 10% chance that Homunculus will re-appear
PrintMessage
The Homunculus has returned.  He is grinning widely, and seems very interested
in what you are doing.
END_Message
BlankLine
PutInCurrentRoom [Homunculus]
END_COMMAND

COMMAND EXAMINE HOMUNCULUS
Present [Homunculus]
DescribeThing [Homunculus]
DoneWithTurn
END_COMMAND

COMMAND ANY HOMUNCULUS
Present [Homunculus]
TurnFlagON [Has met Homunculus]
Chance 5 ; 5% chance that Homunculus will leave
RandomMessage [Homunculus leaves #1] [Homunculus leaves #8]
BlankLine
Destroy [Homunculus]
END_COMMAND

MESSAGE [Homunculus leaves #1]
Losing interest in you, the Homunculus wanders away, scratching his small head
with a very large finger.
END_MESSAGE

MESSAGE [Homunculus leaves #2]
Losing interest in you, the Homunculus wanders away, scratching his small head
with a very large finger.
END_MESSAGE

MESSAGE [Homunculus leaves #3]
Insulted by your behavior action, the Homunculus sneers at you and walks away!
END_MESSAGE

MESSAGE [Homunculus leaves #4]
The Homunculus shrieks with terror as you attempt this, and runs away!
END_MESSAGE

MESSAGE [Homunculus leaves #5]
Before you can try it, the Homunculus scurries out of reach, and disappears!
END_MESSAGE

MESSAGE [Homunculus leaves #6]
Only a fool tries that with a Homunculus!  Fortunately for you, the Homunculus
chooses this moment to wander off.
END_MESSAGE

MESSAGE [Homunculus leaves #7]
This amuses the Homunculus to no end!  His laughter echoes loudly as he leaves
you.
END_MESSAGE

MESSAGE [Homunculus leaves #8]
For some unknown reason, the Homunculus finds this threatening, and heads for
safety.
END_MESSAGE


COMMAND DROP ANY
AtLocationLT [Foramen]
SendNOUNToRoom [Foramen]
PrintMessage
Dropped ...And carried away by the flow of the cerebrospinal fluid!
END_Message
DoneWithTurn
END_COMMAND

FLAG [Ghost has been stained]

COMMAND STAIN GHOST
Present [GolgiStainVial]
Present [GolgiStain]
Present [Thief]
PrintMessage
The crystal shatters against the ghost!

Golgi's Ghost shrieks in terror as he is doused by the stain.  He begins to
glow, and the eerie silver light fills the air.  He runs screaming into the
darkness casting an eerie light as he goes.
END_Message
PlusScore 100
Destroy [GolgiStainVial]
Destroy [GolgiStain]
Destroy [Thief]
DropIT [Glass]
TurnFlagON [Ghost has been stained]
DoneWithTurn
END_COMMAND

COMMAND THROW STAIN
Present [GolgiStainVial]
Present [GolgiStain]
Present [Thief]
PrintMessage
The crystal shatters against the ghost!

Golgi's Ghost shrieks in terror as he is doused by the stain.  He begins to
glow, and the eerie silver light fills the air.  He runs screaming into the
darkness casting an eerie light as he goes.
END_Message
PlusScore 100
Destroy [GolgiStainVial]
Destroy [GolgiStain]
Destroy [Thief]
DropIT [Glass]
TurnFlagON [Ghost has been stained]
DoneWithTurn
END_COMMAND

COMMAND EAT PILL
Present [Pill]
SetVariableTo [Pill Working] 10 ; Pill is now in effect
Destroy [Pill]
PrintMessage "Mmmm... Suddenly you feel very protected."
DoneWithTurn
END_COMMAND

COMMAND EAT HORMONE
Present [GrowthHormone]
SetVariableTo [Growing] 10 ; You are now growing larger
Destroy [GrowthHormone]
PlusScore 100
PrintMessage "Mmmm... you suddenly feel quite a bit stronger."
DoneWithTurn
END_COMMAND


CREATURE [Thief]
Ghost
Golgi's
Golgi's ghost is cowering in a corner, muttering quietly.
LOCATION [NoWhere]
MAN
HOSTILE
END_CREATURE

CREATURE_DESCR [Thief]
He is cowering in a corner, muttering about this invasion of his sanctuary!
END_CREATURE_DESCR


COMMAND ANY
NOT Present [Thief]
NOT Present [Stained Thief]
Chance 5 ; 5% chance of seeing Ghost's aura
FlagON [Ghost has been stained]
PrintMessage
An eerie silver aura begins to fill the room.  Its source is unclear.
END_Message
BlankLine
END_COMMAND

COMMAND ANY
NOT Present [Thief]
NOT Present [Stained Thief]
Chance 5 ; 5% chance of seeing Ghost's aura
FlagON [Ghost has been stained]
PrintMessage
Golgi's ghost suddenly appears.
END_Message
BlankLine
PutInCurrentRoom [Stained Thief]
END_COMMAND

COMMAND ANY
Present [Stained Thief]
Chance 10 ; 10% chance of Ghost disappearing
FlagON [Ghost has been stained]
PrintMessage
Golgi's ghost suddenly disappears, as suddenly as it had appeared.
END_Message
BlankLine
Destroy [Stained Thief]
END_COMMAND

CREATURE [Stained Thief]
Ghost
Golgi's
Golgi's ghost is glowing with an eerie silver light in a corner.
LOCATION [NoWhere]
MAN
GROUPMEMBER
END_CREATURE

CREATURE_DESCR [Stained Thief]
He is cowering in a corner, whimpering quietly.  He has an eerie silver aura.
END_CREATURE_DESCR


COMMAND ANY
NOT AtLocation [Accumbens -- Thief's Lair]
NOT Present [Thief]
Chance 10
IsCarryingTreasure 20
PrintMessage
Golgi's Ghost appears, seemingly from nowhere!  "If you want to live, give me
your treasures!"

Your reluctantly give him your treasures.  He disappears, as mysteriously as
he appeared!
END_Message
SendTreasuresToRoom [Accumbens -- Thief's Lair] 20
SendToRoom [Thief]  [Accumbens -- Thief's Lair]
DoneWithTurn
END_COMMAND


COMMAND ANY
VariableGT [Pill Working] 0 ; pill currently in effect
SubtractFromVariable [Pill Working] 1
VariableEquals [Pill Working] 0 ; pill just wore off
PrintMessage "You feel somehow less protected than you did a moment ago!!!"
BlankLine
END_COMMAND

COMMAND ANY
VariableGT [Growing] 0 ; You are growing larger
SubtractFromVariable [Growing] 1
VariableEquals [Growing] 7
PrintMessage
Things are happening inside of you.  You are feeling much stronger, and could
carry more!
END_Message
BlankLine
END_COMMAND

COMMAND ANY
VariableEquals [Growing] 4
PrintMessage
You are getting larger. Soon you will be too big to move, but your strength is
incredible!!
END_Message
BlankLine
END_COMMAND

COMMAND ANY
VariableEquals [Growing] 1 ; You have become normal size
PrintMessage
You can no longer move, as the growth hormone has taken effect.  You are
crushing the surrounding tissue!

You have now grown to fill the space within the skull, and find it quite
difficult to breathe!

Unable to breathe, you suffocate inside of your own skull!  Descartes arrives,
too late to help, and simply shakes his head in despair.
END_Message
ReDirectTo QUIT
END_COMMAND


COMMAND HELP
RandomMessage [HELP Message 1] [HELP Message 5]
DoneWithTurn
END_COMMAND

MESSAGE [Help Message 1]
You are beyond help!
END_MESSAGE

MESSAGE [Help Message 2]
You must be an optimist!
END_MESSAGE

MESSAGE [Help Message 3]
Solve this problem yourself!
END_MESSAGE

MESSAGE [Help Message 4]
I'm just a dumb computer.
END_MESSAGE

MESSAGE [Help Message 5]
Nice try!  I wish I could help, but I can't.
END_MESSAGE


#COMMENT --------- Amygdala Questions

VARIABLE [Question number]
FLAG [Answered WRONG]
VARIABLE [Number of Wrong Answers]

#COMMENT Ask Amygdala Question *********************
FLAG [Has Answered Amygdala Question CORRECTLY] -- means passages open

MESSAGE [Need to answer Amygdala Question]
To pass in that direction, you must answer a question.  Once the question has
been answered correctly, you will have free access between the amygdala and
the limbic system.
END_MESSAGE


COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Amygdala Question CORRECTLY]
AtLocation [Amygdala]
RandomVariable [Question number] 4 -- 5 questions in total
PrintMessage [Need to answer Amygdala Question]
TurnFlagON [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Amygdala Question CORRECTLY]
AtLocation [Amygdala]
VariableEquals [Question number] 0 -- 1st question
PrintMessage
Who proposed that several limbic structures form a loop that plays a critical
role in the expression of emotion?

    1.  Freud
    2.  Jung
    3.  Papez
    4.  Malmberg
    5.  Welch

END_MESSAGE
GetNumberInput 1 5
NumberEquals 3 -- Papez is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Amygdala Question CORRECTLY]
AtLocation [Amygdala]
VariableEquals [Question number] 1 -- 2nd question
PrintMessage
In general, do lesions of the amygdala facilitate or inhibit aggressive
behavior?

    1.  Facilitate
    2.  Inhibit
    3.  Neither.  They have no effect.

END_MESSAGE
GetNumberInput 1 3
NumberEquals 2 -- Inhibit is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Amygdala Question CORRECTLY]
AtLocation [Amygdala]
VariableEquals [Question number] 2 -- 3rd question
PrintMessage
What syndrome is produced by lesioning the septal area in a rat?

    1.  Sleep
    2.  Aggression
    3.  Happiness
    4.  Hunger
    5.  Bewilderment

END_MESSAGE
GetNumberInput 1 5
NumberEquals 2 -- Aggression is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Amygdala Question CORRECTLY]
AtLocation [Amygdala]
VariableEquals [Question number] 3 -- 4th question
PrintMessage
What sensory system seems to be closely linked to the limbic system?

    1.  Smell
    2.  Taste
    3.  Sight
    4.  Sound
    5.  Touch

END_MESSAGE
GetNumberInput 1 5
NumberEquals 1 -- Smell is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Amygdala Question CORRECTLY]
AtLocation [Amygdala]
VariableEquals [Question number] 4 -- 5th question
PrintMessage
Name one of the two people credited with the theory of emotion that states
that emotions arise as a result of our perception of bodily responses.

    1.  Sigmund Freud
    2.  Karl Jung
    3.  William James
    4.  Fredrick Sneed
    5.  Carl Lange

END_MESSAGE
GetNumberInput 1 5
NumberEquals 3 -- William James is correct answer
OR
NumberEquals 5 -- Carl Lange is also correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Amygdala Question CORRECTLY]
AtLocation [Amygdala]
FlagOFF [Answered WRONG]
TurnFlagON [Has Answered Amygdala Question CORRECTLY]
#COMMENT -- Action for correct answer
PrintMessage

You are absolutely correct!  This answer has opened the limbic system to you.
Try your direction again and the path will be open.
END_MESSAGE
ChangePassageWay [East] [Septum]
ChangePassageWay [South] [Hippocampus];
SetVariableTo [Number of Wrong Answers] 0
DoneWithTurn
END_COMMAND

COMMAND CAUDAL
VerbIsDirection
FlagOFF [Has Answered Amygdala Question CORRECTLY]
AtLocation [Amygdala]
FlagON [Answered WRONG]
AddToVariable [Number of Wrong Answers] 1
ReDirectTo WRONGANSWER
DoneWithTurn
END_COMMAND

COMMAND WRONGANSWER
FlagON [Answered WRONG]
VariableEquals [Number of Wrong Answers] 1 -- first wrong answer
PrintMessage

You will have one more chance to answer a question correctly, or face being
banished to the pineal body by Descartes!
END_MESSAGE
DoneWithTurn
END_COMMAND

COMMAND WRONGANSWER
FlagON [Answered WRONG]
VariableEquals [Number of Wrong Answers] 2 -- second wrong answer
PrintMessage

Descartes appears, quite disappointed. "Two wrong answers in a row.  You have
clearly not yet mastered the material.  You are hereby banished to the pineal
body - yes, the very seat of the soul - where you must forever contemplate the
brain in all of its wonder.
END_MESSAGE
EndGame -- It is all over!  You blew it!
DoneWithTurn
END_COMMAND



#COMMENT --------- Visual Cx Questions

#COMMENT Ask Visual Cx Question *********************
FLAG [Has Answered Visual Cx Question CORRECTLY] -- means passages open

MESSAGE [Need to answer Visual Cx Question]
To leave the striate cortex you must answer a question.  If you answer
correctly, you will be transported to a random location elsewhere in the
brain.  Dire consequences await you if your answer is incorrect!
END_MESSAGE

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Visual Cx Question CORRECTLY]
AtLocation [Visual Cx]
RandomVariable [Question number] 7 -- 8 questions in total
PrintMessage [Need to answer Visual Cx Question]
TurnFlagON [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Visual Cx Question CORRECTLY]
AtLocation [Visual Cx]
VariableEquals [Question number] 0 -- 1st question
PrintMessage
What hypothalamic nucleus plays a role in circadian rhythms?

    1.  Stocastic Nucleus
    2.  Jung's Nucleus
    3.  Papez's Nucleus
    4.  Suprachiasmatic Nucleus
    5.  Homoeripian Nucleus

END_MESSAGE
GetNumberInput 1 5
NumberEquals 4 -- Suprachiasmatic Nucleus is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Visual Cx Question CORRECTLY]
AtLocation [Visual Cx]
VariableEquals [Question number] 1 -- 2nd question
PrintMessage
Where do optic nerve fibers decussate?

    1.  Stocastic Nucleus
    2.  Optic Chiasma
    3.  Chiasma Nucleus
    4.  Optic Suprachiasmatic
    5.  Optic Homoeripian

END_MESSAGE
GetNumberInput 1 5
NumberEquals 2 -- Optic Chiasma is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Visual Cx Question CORRECTLY]
AtLocation [Visual Cx]
VariableEquals [Question number] 2 -- 3rd question
PrintMessage
In the periphery, bundles of axons are called nerves.  What are bundles of
axons in the central nervous system called?

    1.  Nervous Nucleus
    2.  Chiasma
    3.  Central Axons
    4.  Suprachiasmatic
    5.  Tracts

END_MESSAGE
GetNumberInput 1 5
NumberEquals 5 -- Tracts is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Visual Cx Question CORRECTLY]
AtLocation [Visual Cx]
VariableEquals [Question number] 3 -- 4th question
PrintMessage
In what lobe of the cortex is the primary visual area located?

    1.  Cortex Nucleus
    2.  Chiasma
    3.  Visual Axons
    4.  Suprachiasmatic
    5.  Occipital

END_MESSAGE
GetNumberInput 1 5
NumberEquals 5 -- Occipital is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Visual Cx Question CORRECTLY]
AtLocation [Visual Cx]
VariableEquals [Question number] 4 -- 5th question
PrintMessage
What part of the brain contains the superior colliculus?

    1.  Cortex Nucleus
    2.  Tectum Midbrain Mesencephalon
    3.  Axons Superior
    4.  Suprachiasmatic Superior
    5.  Occipital Nucleus

END_MESSAGE
GetNumberInput 1 5
NumberEquals 2 -- Tectum Midbrain Mesencephalon is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Visual Cx Question CORRECTLY]
AtLocation [Visual Cx]
VariableEquals [Question number] 5 -- 6th question
PrintMessage
What is the name of the thalamic relay nucleus for visual information?

    1.  Cortex Nucleus
    2.  Tectum Mesencephalon
    3.  Lateral Geniculate Nucleus
    4.  Suprachiasmatic Superior
    5.  Occipital Nucleus

END_MESSAGE
GetNumberInput 1 5
NumberEquals 3 -- Lateral Geniculate Nucleus is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Visual Cx Question CORRECTLY]
AtLocation [Visual Cx]
VariableEquals [Question number] 6 -- 7th question
PrintMessage
Name one of the three people who received the Nobel prize in medicine for
their work on visual system physiology.

    1.  Freud
    2.  Jung
    3.  Hubel
    4.  Sneed
    5.  Weisel
    6.  Sperry
    7.  Fredricks
    8.  Smithson
    9.  Seelenfreund
    10. Malson

END_MESSAGE
GetNumberInput 1 10
NumberEquals 3 -- Hubel is correct answer
OR
NumberEquals 5 -- Weisel is also a correct answer
OR
NumberEquals 6 -- Sperry is also a correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Visual Cx Question CORRECTLY]
AtLocation [Visual Cx]
VariableEquals [Question number] 7 -- 8th question
PrintMessage
What kind of cells in the retina provide the axons that make up the optic
nerve?

    1.  Cortex Cells
    2.  Tectum Mesencephalon Axons
    3.  Ganglion Cells
    4.  Suprachiasmatic Cells
    5.  Occipital Axons

END_MESSAGE
GetNumberInput 1 5
NumberEquals 3 -- Ganglion Cells is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Visual Cx Question CORRECTLY]
AtLocation [Visual Cx]
FlagOFF [Answered WRONG]
TurnFlagON [Has Answered Visual Cx Question CORRECTLY]
#COMMENT -- Action for correct answer
PrintMessage

That is absolutely correct!  Because you knew the answer, you will be
transported to...
END_MESSAGE
SetVariableTo [Number of Wrong Answers] 0
ReDirectTo MOVERANDOMLY
DoneWithTurn
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Visual Cx Question CORRECTLY]
AtLocation [Visual Cx]
FlagON [Answered WRONG]
AddToVariable [Number of Wrong Answers] 1
ReDirectTo WRONGANSWER
DoneWithTurn
END_COMMAND

COMMAND MOVERANDOMLY
#COMMENT -- Action for correct answer
GoToRandomRoom [Putamen] [Assoc3]
NOT AtLocation [Accumbens -- Thief's Lair]
NOT AtLocation [Amygdala]
NOT AtLocation [Pyramids]
NOT AtLocation [Pituitary]
NOT AtLocation [Visual Cx]
NOT AtLocation [Trapezoid Body]
DoneWithTurn
END_COMMAND

COMMAND MOVERANDOMLY
#COMMENT -- Action for correct answer
GoToRandomRoom [Putamen] [Assoc3]
NOT AtLocation [Accumbens -- Thief's Lair]
NOT AtLocation [Amygdala]
NOT AtLocation [Pyramids]
NOT AtLocation [Pituitary]
NOT AtLocation [Visual Cx]
NOT AtLocation [Trapezoid Body]
DoneWithTurn
END_COMMAND

COMMAND MOVERANDOMLY
#COMMENT -- Action for correct answer
GoToRoom [Putamen]
DoneWithTurn
END_COMMAND


#COMMENT --------- Pituitary Questions

#COMMENT Ask Pituitary Question *********************
FLAG [Has Answered Pituitary Question CORRECTLY] -- means passages open

MESSAGE [Need to answer Pituitary Question]
A question must be answered correctly in order to leave the pituitary.  A
correct answer will send you randomly to another part of the brain.  For your
own sake, do NOT answer incorrectly!
END_MESSAGE

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pituitary Question CORRECTLY]
AtLocation [Pituitary]
RandomVariable [Question number] 3 -- 4 questions in total
PrintMessage [Need to answer Pituitary Question]
TurnFlagON [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pituitary Question CORRECTLY]
AtLocation [Pituitary]
VariableEquals [Question number] 0 -- 1st question
PrintMessage
What is the name of the stalk that attaches the pituitary to the hypothalamus?

    1.  Stocastical Hypo
    2.  Infundibulum
    3.  Papez's Stalk
    4.  Suprachiasmaticon
    5.  Homoeripian Stalk

END_MESSAGE
GetNumberInput 1 5
NumberEquals 2 -- Infundibulum is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pituitary Question CORRECTLY]
AtLocation [Pituitary]
VariableEquals [Question number] 1 -- 2nd question
PrintMessage
What hormone promotes the masculinization of the brain?

    1.  Testosterone
    2.  Homo Sapian Hormone
    3.  Chiasma Hormone
    4.  Suprachiasma
    5.  Homoeripia

END_MESSAGE
GetNumberInput 1 5
NumberEquals 1 -- Testosterone is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pituitary Question CORRECTLY]
AtLocation [Pituitary]
VariableEquals [Question number] 2 -- 3rd question
PrintMessage
What diencephalic structure controls the release of hormones from the
pituitary?

    1.  Diencephalic 2
    2.  Chiasmathalmus
    3.  Pituitary Axons
    4.  Suprachiasmatica
    5.  Hypothalamus

END_MESSAGE
GetNumberInput 1 5
NumberEquals 5 -- Hypothalamus is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pituitary Question CORRECTLY]
AtLocation [Pituitary]
VariableEquals [Question number] 3 -- 4th question
PrintMessage
What hormone, released from the pituitary at the onset of puberty, promotes
increased function of the testes or ovaries?

    1.  Cortex Hormone
    2.  Hypothalamus Hormone
    3.  Gonadotropic Hormone
    4.  Suprachiasmatica Hormone
    5.  Occipital Hormone

END_MESSAGE
GetNumberInput 1 5
NumberEquals 3 -- Gonadotropic Hormone is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pituitary Question CORRECTLY]
AtLocation [Pituitary]
FlagOFF [Answered WRONG]
TurnFlagON [Has Answered Pituitary Question CORRECTLY]
#COMMENT -- Action for correct answer
PrintMessage

That is absolutely correct!  Because you knew the answer, you will be
transported to...
END_MESSAGE
SetVariableTo [Number of Wrong Answers] 0
ReDirectTo MOVERANDOMLY
DoneWithTurn
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pituitary Question CORRECTLY]
AtLocation [Pituitary]
FlagON [Answered WRONG]
AddToVariable [Number of Wrong Answers] 1
ReDirectTo WRONGANSWER
DoneWithTurn
END_COMMAND


#COMMENT --------- Trapezoid Body Questions

#COMMENT Ask Trapezoid Body Question *********************
FLAG [Has Answered Trapezoid Body Question CORRECTLY] -- means passages open

MESSAGE [Need to answer Trapezoid Body Question]
To leave this brainstem auditory nucleus, you must answer a question.  A
correct answer will send you to another region of the brain.  An incorrect
answer will be dealt with severely!
END_MESSAGE

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Trapezoid Body Question CORRECTLY]
AtLocation [Trapezoid Body]
RandomVariable [Question number] 7 -- 8 questions in total
PrintMessage [Need to answer Trapezoid Body Question]
TurnFlagON [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Trapezoid Body Question CORRECTLY]
AtLocation [Trapezoid Body]
VariableEquals [Question number] 0 -- 1st question
PrintMessage
What is the name for the language impairment that results from damage to
Broca's or Wernicke's area?

    1.  Stuttering
    2.  Aphasia
    3.  Papez's Sickness
    4.  Suprachiasmatic Impairment
    5.  Homoeripia

END_MESSAGE
GetNumberInput 1 5
NumberEquals 2 -- Aphasia is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Trapezoid Body Question CORRECTLY]
AtLocation [Trapezoid Body]
VariableEquals [Question number] 1 -- 2nd question
PrintMessage
What major fissure lies just superior to the auditory cortex?

    1.  Stock's Fissure
    2.  Lateral Fissure
    3.  Chiasma Fissure
    4.  Major Auditory Fissure
    5.  Cortex Fissure

END_MESSAGE
GetNumberInput 1 5
NumberEquals 2 -- Lateral Fissure is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Trapezoid Body Question CORRECTLY]
AtLocation [Trapezoid Body]
VariableEquals [Question number] 2 -- 3rd question
PrintMessage
In the periphery, bundles of axons are called nerves.  What are bundles of
axons in the central nervous system called?

    1.  Nervous Nucleus
    2.  Chiasma
    3.  Central Axons
    4.  Suprachiasmatic
    5.  Tracts

END_MESSAGE
GetNumberInput 1 5
NumberEquals 5 -- Tracts is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Trapezoid Body Question CORRECTLY]
AtLocation [Trapezoid Body]
VariableEquals [Question number] 3 -- 4th question
PrintMessage
What is the name of the largest band of fibers interconnecting the two
hemispheres of the brain?

    1.  Cortex Nucleus
    2.  Chiasma Corpus
    3.  Arterial Axons
    4.  Suprachiasmatic Fibers
    5.  Corpus Callosum

END_MESSAGE
GetNumberInput 1 5
NumberEquals 5 -- Corpus Callosum is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Trapezoid Body Question CORRECTLY]
AtLocation [Trapezoid Body]
VariableEquals [Question number] 4 -- 5th question
PrintMessage
The thalamus receives afferent projections from every sensory system except
which one?

    1.  Olfaction
    2.  Taste
    3.  Sight
    4.  Sound
    5.  Touch

END_MESSAGE
GetNumberInput 1 5
NumberEquals 1 -- Olfaction (i.e., Smell) is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Trapezoid Body Question CORRECTLY]
AtLocation [Trapezoid Body]
VariableEquals [Question number] 5 -- 6th question
PrintMessage
In what lobe is the auditory cortex located?

    1.  Cortex Lobe
    2.  Tectum Mesencephalon Lobe
    3.  Lateral
    4.  Suprachiasmatic Superior
    5.  Temporal

END_MESSAGE
GetNumberInput 1 5
NumberEquals 5 -- Temporal is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Trapezoid Body Question CORRECTLY]
AtLocation [Trapezoid Body]
VariableEquals [Question number] 6 -- 7th question
PrintMessage
Which of the aphasias is characterized by fluent but meaningless speech?

    1.  Freud's Aphasia
    2.  Jung's Aphasia
    3.  Hubel's Aphasia
    4.  Wernicke's Aphasia
    5.  Weisel's Aphasia
    6.  Sperry's Aphasia
    7.  Fredricks's Aphasia
    8.  Smithson's Aphasia
    9.  Seelenfreund's Aphasia
    10. Malson's Aphasia

END_MESSAGE
GetNumberInput 1 10
NumberEquals 4 -- Wernicke's Aphasia is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Trapezoid Body Question CORRECTLY]
AtLocation [Trapezoid Body]
VariableEquals [Question number] 7 -- 8th question
PrintMessage
What is the name of the membrane within the ear that contains the hair cells,
and vibrates in response to sound?

    1.  Basilar Membrane
    2.  Tectum Mesencephalon Axons
    3.  Ganglion Membrane
    4.  Suprachiasmatic Membrane
    5.  Occipital Membrane

END_MESSAGE
GetNumberInput 1 5
NumberEquals 1 -- Basilar Membrane is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Trapezoid Body Question CORRECTLY]
AtLocation [Trapezoid Body]
FlagOFF [Answered WRONG]
TurnFlagON [Has Answered Trapezoid Body Question CORRECTLY]
#COMMENT -- Action for correct answer
PrintMessage

That is absolutely correct!  Because you knew the answer, you will be
transported to...
END_MESSAGE
SetVariableTo [Number of Wrong Answers] 0
ReDirectTo MOVERANDOMLY
DoneWithTurn
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Trapezoid Body Question CORRECTLY]
AtLocation [Trapezoid Body]
FlagON [Answered WRONG]
AddToVariable [Number of Wrong Answers] 1
ReDirectTo WRONGANSWER
DoneWithTurn
END_COMMAND


#COMMENT --------- Pyramids Questions

#COMMENT Ask Pyramids Question *********************
FLAG [Has Answered Pyramids Question CORRECTLY] -- means passages open

MESSAGE [Need to answer Pyramids Question]
You have reached the end of the road, so to speak, and must answer a question
to leave this area.  Do NOT answer incorrectly!
END_MESSAGE

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pyramids Question CORRECTLY]
AtLocation [Pyramids]
RandomVariable [Question number] 6 -- 7 questions in total
PrintMessage [Need to answer Pyramids Question]
TurnFlagON [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pyramids Question CORRECTLY]
AtLocation [Pyramids]
VariableEquals [Question number] 0 -- 1st question
PrintMessage
Are the pyramids in primarily an afferent or efferent pathway?

    1.  Efferent
    2.  Afferent
    3.  Neither, they are not a pathway.

END_MESSAGE
GetNumberInput 1 3
NumberEquals 1 -- Efferent is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pyramids Question CORRECTLY]
AtLocation [Pyramids]
VariableEquals [Question number] 1 -- 2nd question
PrintMessage
If you, at your present size, got a job as a neurotransmitter at a
neuromuscular junction, what neurotransmitter would you become (if you wanted
to keep your job, that is)?

    1.  Stochastica Neurotransmitter
    2.  Lateral Neurtron
    3.  Chiasma Nuclei
    4.  Acetylcholine
    5.  Cortex Neurotransmitter

END_MESSAGE
GetNumberInput 1 5
NumberEquals 4 -- Acetylcholine is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pyramids Question CORRECTLY]
AtLocation [Pyramids]
VariableEquals [Question number] 2 -- 3rd question
PrintMessage
In what lobe is the motor strip located?

    1.  Nucleus Lobe
    2.  Frontal
    3.  Central
    4.  Suprachiasmatic Lobe
    5.  Tracts

END_MESSAGE
GetNumberInput 1 5
NumberEquals 2 -- Frontal is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pyramids Question CORRECTLY]
AtLocation [Pyramids]
VariableEquals [Question number] 3 -- 4th question
PrintMessage
What basal ganglion structure, along with the globus pallidus, makes up the
lentiform or lenticular nucleus?

    1.  Cortex Ganglion
    2.  Putamen
    3.  Arterial Ganglion
    4.  Suprachiasmatica
    5.  Corpus Callosum

END_MESSAGE
GetNumberInput 1 5
NumberEquals 2 -- Putamen is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pyramids Question CORRECTLY]
AtLocation [Pyramids]
VariableEquals [Question number] 4 -- 5th question
PrintMessage
What type of cell gives rise to the axons that pass through the pyramids in
the corticospinal tract?

    1.  Diencephalic T-Cells
    2.  Chiasmathalmus Cells
    3.  Betz Cells
    4.  Pyramidal Cells
    5.  Hypothalamus Axon
    6.  Putamen Axon
    7.  Arterial Ganglion Cells
    8.  Suprachiasmatica Cells
    9.  Callosum Cells

END_MESSAGE
GetNumberInput 1 9
NumberEquals 3 -- Betz Cells is correct answer
OR
NumberEquals 4 -- Pyramidal Cells is also correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pyramids Question CORRECTLY]
AtLocation [Pyramids]
VariableEquals [Question number] 5 -- 6th question
PrintMessage
Loss of the dopaminergic cells of the substantia nigra results in what
clinical condition?

    1.  Blindness
    2.  Stuttering
    3.  Lateral Tendenitis
    4.  Parkinson's Disease
    5.  Temporal Brain Fever

END_MESSAGE
GetNumberInput 1 5
NumberEquals 4 -- Parkinson's Disease is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pyramids Question CORRECTLY]
AtLocation [Pyramids]
VariableEquals [Question number] 6 -- 7th question
PrintMessage
What structure is presumed to be involved with the execution of skilled,
coordinated movements?

    1.  Hypothalamus
    2.  Putamen
    3.  Arterial Ganglion
    4.  Cerebellum
    5.  Seelenfreund's Aphasia

END_MESSAGE
GetNumberInput 1 5
NumberEquals 4 -- Cerebellum is correct answer
TurnFlagOFF [Answered WRONG]
BlankLine
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pyramids Question CORRECTLY]
AtLocation [Pyramids]
FlagOFF [Answered WRONG]
TurnFlagON [Has Answered Pyramids Question CORRECTLY]
#COMMENT -- Action for correct answer
PrintMessage

That is absolutely correct!  Because you knew the answer, you will be
transported to...
END_MESSAGE
SetVariableTo [Number of Wrong Answers] 0
ReDirectTo MOVERANDOMLY
DoneWithTurn
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagOFF [Has Answered Pyramids Question CORRECTLY]
AtLocation [Pyramids]
FlagON [Answered WRONG]
AddToVariable [Number of Wrong Answers] 1
ReDirectTo WRONGANSWER
DoneWithTurn
END_COMMAND


;QUIT COMMANDS

MESSAGE [Do you really want to quit?]
Are you sure you want to quit?
END_MESSAGE

MESSAGE [Thank you for playing BRAINSCAPE!]

Thank you for playing BRAINSCAPE!!
END_MESSAGE

MESSAGE [I didn't think you really wanted to quit!]
I didn't think you really wanted to quit!

END_MESSAGE

FLAG [Quitting]

COMMAND QUIT
FlagOn [Quitting]
GoToRoom [WakeUp]
DoneWithTurn
END_COMMAND

COMMAND QUIT
PrintMessage [Do you really want to quit?]
PromptForYes (* Get YES or NO answer from keyboard *)
PrintMessage [Thank you for playing BRAINSCAPE!]
EndGame (* OK, player entered YES -- so let's quit *)
TurnFlagON [Quitting]
ReDirectTo SCORE
END_COMMAND

COMMAND QUIT
TurnFlagOFF [Quitting]
PrintMessage [I didn't think you really wanted to quit!]
BlankLine
ReDirectTo LOOK
END_COMMAND

#COMMENT -- score is based on Max_Points of [Perfect SCORE]

#DEFINE [1st SCORE Breakpoint]      200
#DEFINE [1st SCORE Breakpoint + 1]  201
#DEFINE [2nd SCORE Breakpoint]      400
#DEFINE [2nd SCORE Breakpoint + 1]  401
#DEFINE [3rd SCORE Breakpoint]      600
#DEFINE [3rd SCORE Breakpoint + 1]  601
#DEFINE [4th SCORE Breakpoint]      800
#DEFINE [4th SCORE Breakpoint + 1]  801
#DEFINE [5th SCORE Breakpoint]      1000
#DEFINE [5th SCORE Breakpoint + 1]  1001
#DEFINE [Perfect SCORE]             1150

COMMAND SCORE
BlankLine
PrintMessage "Descartes appears suddenly."
END_COMMAND

COMMAND SCORE
ScoreLT [1st SCORE Breakpoint + 1] ; less than 201
BlankLine
PrintMessage
"Your score is terrible!  I expected so much from you, and I am sorely
disappointed", he sighs.  "To have been so close to a full understanding of
the brain, and to have failed!  I shall return to my studies, and hope that,
in the future, someone else will succeed in uncovering the knowledge that lies
in the brain.  This is my ultimate dream."
END_MESSAGE
END_COMMAND

COMMAND SCORE
ScoreLT [2nd SCORE Breakpoint + 1] ; less than 401
ScoreGT [1st SCORE Breakpoint]     ; greater than 200
BlankLine
PrintMessage
"Your score is very poor.  You are only beginning to discover what awaits you
within your head.  You should try to learn more of the mysteries of the
brain."
END_MESSAGE
END_COMMAND

COMMAND SCORE
ScoreLT [3rd SCORE Breakpoint + 1] ; less than 601
ScoreGT [2nd SCORE Breakpoint]     ; greater than 400
BlankLine
PrintMessage
"Good!  You have made considerable progress toward furthering your knowledge
of the brain.  However, you have much more to learn."
END_MESSAGE
END_COMMAND

COMMAND SCORE
ScoreLT [4th SCORE Breakpoint + 1] ; less than 801
ScoreGT [3rd SCORE Breakpoint]     ; greater than 600
BlankLine
PrintMessage
"Very good!  You have scored well!  This score indicates that your knowledge
of the brain has grown considerably, but there is still more to be learned.
Try again!  Explore further!"
END_MESSAGE
END_COMMAND

COMMAND SCORE
ScoreLT [5th SCORE Breakpoint + 1] ; less than 1001
ScoreGT [4th SCORE Breakpoint]     ; greater than 800
BlankLine
PrintMessage
"A remarkable achievement!  You are nearing a complete understanding of the
brain!  Persevere!  There are still some aspects of the brain to be
discovered.  I am quite certain that you are capable of a most complete
exploration."
END_MESSAGE
END_COMMAND

COMMAND SCORE
ScoreLT [Perfect SCORE] ; less than 1150
ScoreGT [5th SCORE Breakpoint]     ; greater than 1000
BlankLine
PrintMessage
"Your score is approaching perfection!  You are so very close to a perfect
score of 1150 points.  Try again. I know that this score is within your
reach."
END_MESSAGE
END_COMMAND

COMMAND SCORE
ScoreEquals [Perfect SCORE] ; 1150 points
BlankLine
PrintMessage
"A perfect score of 1150!  Never have I seen such an achievement!  You have
learned more about the brain than I knew in my day, and more than many people
know today.  Congratulations on this most wonderous accomplishment!"
END_MESSAGE
END_COMMAND

COMMAND SCORE
BlankLine
FlagOn [Quitting]
ReDirectTo QUIT
END_COMMAND



